Справочник MQL5Математические функцииMathClassify

MathClassify

Определяет тип вещественного числа и возвращает результат в виде значения из перечисления ENUM_FP_CLASS

ENUM_FP_CLASS  MathClassify(
   double  value      // вещественное число
   );

Параметры

value

[in] Проверяемое вещественное число

Возвращаемое значение

Значениe из перечисления ENUM_FP_CLASS

ENUM_FP_CLASS

Идентификатор	Описание
FP_SUBNORMAL	Субнормальное число, которое находится ближе к нулю, чем наименьшее представимое нормализованное число DBL_MIN (2.2250738585072014e-308)
FP_NORMAL	Нормализованное число, которое находится в диапазоне от 2.2250738585072014e-308 до 1.7976931348623158e+308
FP_ZERO	Положительный или отрицательный ноль
FP_INFINITE	Число, которое не может быть представлено соответствующим типом — положительная или отрицательная бесконечность
FP_NAN	Не является числом

Пример:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
{
//--- test NaN
  double nan=double("nan");
  PrintFormat("Test NaN: %G is %s, MathIsValidNumber(NaN)=%s",
              nan,
              EnumToString(MathClassify(nan)),
              (string)MathIsValidNumber(nan));
//--- test infinity
  double inf=double("inf");
  PrintFormat("Test Inf: %G is %s, MathIsValidNumber(inf)=%s",
              inf,
              EnumToString(MathClassify(inf)),
              (string)MathIsValidNumber(inf));
//--- test normal value
  double normal=1.2345e6;
  PrintFormat("Test Normal: %G is %s, MathIsValidNumber(normal)=%s",
              normal,
              EnumToString(MathClassify(normal)),
              (string)MathIsValidNumber(normal));
//--- test subnormal value
  double sub_normal=DBL_MIN/2.0;
  PrintFormat("Test Subnormal: %G is %s, MathIsValidNumber(sub_normal)=%s",
              sub_normal,
              EnumToString(MathClassify(sub_normal)),
              (string)MathIsValidNumber(sub_normal));
//--- test zero value
  double zero=0.0/(-1);
  PrintFormat("Test Zero: %G is %s, MathIsValidNumber(zero)=%s",
              zero,
              EnumToString(MathClassify(zero)),
              (string)MathIsValidNumber(zero));
}
/*
Результат:
   Test NaN: NAN is FP_NAN, MathIsValidNumber(NaN)=false
   Test Inf: INF is FP_INFINITE, MathIsValidNumber(inf)=false
   Test Normal: 1.2345E+06 is FP_NORMAL, MathIsValidNumber(normal)=true
   Test Subnormal: 1.11254E-308 is FP_SUBNORMAL, MathIsValidNumber(sub_normal)=true
   Test Zero: -0 is FP_ZERO, MathIsValidNumber(zero)=true
*/
//+------------------------------------------------------------------+

Смотри также

Вещественные типы (double, float), MathIsValidNumber

MathArctan2

MathCeil