Referência MQL5Funções MatemáticasMathClassify

MathClassify

Determina o tipo de um número real e retorna o resultado como um valor da enumeração ENUM_FP_CLASS

ENUM_FP_CLASS  MathClassify(
   double  value      // número real
   );

Parâmetros

value

[in] Número real verificado

Valor retornado

Valor a partir da enumeração ENUM_FP_CLASS

ENUM_FP_CLASS

Identificador	Descrição
FP_SUBNORMAL	Número subnormal que está mais próximo de zero do que do menor número normalizado representável DBL_MIN (2.2250738585072014e-308)
FP_NORMAL	Número normalizado que varia de 2,2250738585072014e-308 a 1,7976931348623158e+308
FP_ZERO	Zero positivo ou negativo
FP_INFINITE	Número que não pode ser representado pelo tipo correspondente - infinito positivo ou negativo
FP_NAN	Não é um número

Exemplo:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
{
//--- test NaN
  double nan=double("nan");
  PrintFormat("Test NaN: %G is %s, MathIsValidNumber(NaN)=%s",
              nan,
              EnumToString(MathClassify(nan)),
              (string)MathIsValidNumber(nan));
//--- test infinity
  double inf=double("inf");
  PrintFormat("Test Inf: %G is %s, MathIsValidNumber(inf)=%s",
              inf,
              EnumToString(MathClassify(inf)),
              (string)MathIsValidNumber(inf));
//--- test normal value
  double normal=1.2345e6;
  PrintFormat("Test Normal: %G is %s, MathIsValidNumber(normal)=%s",
              normal,
              EnumToString(MathClassify(normal)),
              (string)MathIsValidNumber(normal));
//--- test subnormal value
  double sub_normal=DBL_MIN/2.0;
  PrintFormat("Test Subnormal: %G is %s, MathIsValidNumber(sub_normal)=%s",
              sub_normal,
              EnumToString(MathClassify(sub_normal)),
              (string)MathIsValidNumber(sub_normal));
//--- test zero value
  double zero=0.0/(-1);
  PrintFormat("Test Zero: %G is %s, MathIsValidNumber(zero)=%s",
              zero,
              EnumToString(MathClassify(zero)),
              (string)MathIsValidNumber(zero));
}
/*
Result:
   Test NaN: NAN is FP_NAN, MathIsValidNumber(NaN)=false
   Test Inf: INF is FP_INFINITE, MathIsValidNumber(inf)=false
   Test Normal: 1.2345E+06 is FP_NORMAL, MathIsValidNumber(normal)=true
   Test Subnormal: 1.11254E-308 is FP_SUBNORMAL, MathIsValidNumber(sub_normal)=true
   Test Zero: -0 is FP_ZERO, MathIsValidNumber(zero)=true
*/
//+------------------------------------------------------------------+

Veja também

Tipos reais (double, float), MathIsValidNumber

MathArctan2

MathCeil