MathCos

double  MathCos(
   double  value      // число
   );

#define GRAPH_WIDTH  750
#define GRAPH_HEIGHT 350
 
#include <Graphics\Graphic.mqh>
 
CGraphic ExtGraph;
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   vector delta=vector::Full(101,2*M_PI/100);
   delta[0]=0;
//--- получим 101 значение от 0 до 2 пи с шагом delta
   vector X=delta.CumSum();
//--- рассчитываем значение косинуса для каждого значения вектора X
   vector Y=MathCos(X);
 
//--- переносим рассчитанные значения из векторов в массивы
   double x_array[],y_array[];
   X.Swap(x_array);
   Y.Swap(y_array);
 
//--- нарисуем график рассчитанных значений вектора
   CurvePlot(x_array,y_array,clrDodgerBlue);
 
//--- ожидаем нажатия клавиш Escape или PgDn для удаления графика (создания скриншота) и завершения работы
   while(!IsStopped())
     {
      if(StopKeyPressed())
         break;
      Sleep(16);
     }
 
//--- чистим за собой
   ExtGraph.Destroy();
  }
//+------------------------------------------------------------------+
//| При нажатии ESC возвращает true                                  |
//| При нажатии PgDn делает скриншот графика и возвращает true       |
//| Иначе - возвращает false                                         |
//+------------------------------------------------------------------+
bool StopKeyPressed()
  {
//--- если нажата ESC - возвращаем true
   if(TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)!=0)
      return(true);
//--- если нажата PgDn и успешно сделан скриншот графика - возвращаем true
   if(TerminalInfoInteger(TERMINAL_KEYSTATE_PAGEDOWN)!=0 && MakeAndSaveScreenshot(MQLInfoString(MQL_PROGRAM_NAME)+"_Screenshot"))
      return(true);
//--- возвращаем false 
   return(false);
  }
//+------------------------------------------------------------------+
//| Создаёт объект-график и рисует кривую                            |
//+------------------------------------------------------------------+
void CurvePlot(double &x_array[], double &y_array[], const color colour)
  {
   ExtGraph.Create(ChartID(), "Graphic", 0, 0, 0, GRAPH_WIDTH, GRAPH_HEIGHT);
   ExtGraph.CurveAdd(x_array, y_array, ColorToARGB(colour), CURVE_LINES);
   ExtGraph.IndentUp(30);
   ExtGraph.CurvePlotAll();
   string text1="Press ESC to delete the graph and stop the script, or";
   string text2="Press PgDn to create a screen, delete the graph and stop the script";
   ExtGraph.TextAdd(54, 9, text1, ColorToARGB(clrBlack));
   ExtGraph.TextAdd(54,21, text2, ColorToARGB(clrBlack));
   ExtGraph.Update();
  }
//+------------------------------------------------------------------+
//| Создаёт скриншот экрана и сохраняет изображение в файл           |
//+------------------------------------------------------------------+
bool MakeAndSaveScreenshot(const string file_name)
  {
   string file_names[];
   ResetLastError();
   int selected=FileSelectDialog("Save Picture", NULL, "All files (*.*)|*.*", FSD_WRITE_FILE, file_names, file_name+".png");
   if(selected<1)
     {
      if(selected<0)
         PrintFormat("%s: FileSelectDialog() function returned error %d", __FUNCTION__, GetLastError());
      return false;
     }
   
   bool res=false;
   if(ChartSetInteger(0,CHART_SHOW,false))
      res=ChartScreenShot(0, file_names[0], GRAPH_WIDTH, GRAPH_HEIGHT);
   ChartSetInteger(0,CHART_SHOW,true);
   return(res);
  }