//--- 설명
#property description "스크립트는 차트에 타원을 생성합니다."
#property description "고정점 좌표가 설정되었습니다"
#property description "차트 창 크기의 백분율."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpName="Ellipse"; // 타원 이름
input int InpDate1=30; // 첫 번째 점 날짜(%)
input int InpPrice1=20; // 첫 번째 점 가격(%)
input int InpDate2=70; // 두 번째 점 날짜(%)
input int InpPrice2=80; // 두 번째 점 가격(%)
input int InpDate3=50; // 세 번째 점 날짜(%)
input int InpPrice3=60; // 세 번째 점 가격(%)
input color InpColor=clrRed; // 타원 색상
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // 타원 선 스타일
input int InpWidth=2; // 타원 선 너비
input bool InpFill=false; // 타원 색상 채우기
input bool InpBack=false; // 배경 타원
input bool InpSelection=true; // 이동하려면 강조 표시
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 주어진 좌표를 기준으로 타원 생성 |
//+------------------------------------------------------------------+
bool EllipseCreate(const long chart_ID=0, // 차트의 ID
const string name="Ellipse", // 타원 이름
const int sub_window=0, // 하위 창 인덱스
datetime time1=0, // 첫 번째 점 시간
double price1=0, // 첫 번째 점 가격
datetime time2=0, // 두 번째 점 시간
double price2=0, // 두 번째 점 가격
datetime time3=0, // 세 번째 점 시간
double price3=0, // 세 번째 점 가격
const color clr=clrRed, // 타원 색상
const ENUM_LINE_STYLE style=STYLE_SOLID, // 타원 선 스타일
const int width=1, // 타원 선 너비
const bool fill=false, // 타원 색상 채우기
const bool back=false, // 배경에
const bool selection=true, // 이동하려면 강조 표시
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 고정점이 설정되지 않은 경우 고정점의 좌표 설정
ChangeEllipseEmptyPoints(time1,price1,time2,price2,time3,price3);
//--- 오류 값 재설정
ResetLastError();
//--- 주어진 좌표를 기준으로 타원 생성
if(!ObjectCreate(chart_ID,name,OBJ_ELLIPSE,sub_window,time1,price1,time2,price2,time3,price3))
{
Print(__FUNCTION__,
": 타원 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 타원 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 타원 선 스타일 설정
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 타원 선 너비 설정
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 타원 채우기 모드 활성화(참) 또는 비활성화(수정)
ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 이동할 타원 강조 표시 모드를 활성화(true) 또는 비활성화(false)
//--- ObjectCreate 함수를 사용하여 그래픽 개체를 만드는 경우 개체는
//--- 기본적으로 강조 표시되고 이동됩니다. 이 메서드 내에서 선택 매개변수
//--- 기본적으로 true이므로 개체를 강조 표시하고 이동할 수 있습니다.
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 타원 고정점 이동 |
//+------------------------------------------------------------------+
bool EllipsePointChange(const long chart_ID=0, // 차트의 ID
const string name="Ellipse", // 타원 이름
const int point_index=0, // 고정점 인덱스
datetime time=0, // 고정점 시간 좌표
double price=0) // 고정점 가격 좌표
{
//--- 포인트 위치가 설정되지 않은 겨우 입찰 가격이 있는 현재 막대로 이동합니다
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 오류 값 재설정
ResetLastError();
//--- 고정점 이동
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": 고정점 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 타원 삭제 |
//+------------------------------------------------------------------+
bool EllipseDelete(const long chart_ID=0, // 차트의 ID
const string name="Ellipse") // 타원의 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 타원 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": 타원 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 타원 고정점 값 확인 및 기본값 설정 |
//| 빈 곳의 경우 |
//+------------------------------------------------------------------+
void ChangeEllipseEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2,
datetime &time3,double &price3)
{
//--- 첫 번째 점의 시간이 설정되지 않은 경우 현재 막대에 표시됩니다
if(!time1)
time1=TimeCurrent();
//--- 첫 번째 점의 가격이 설정되지 않은 경우 입찰 값을 갖습니다
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 두 번째 점의 시간이 설정되지 않은 경우 두 번째 점에서 남은 9 막대가 위치합니다
if(!time2)
{
//--- 마지막 10개 막대가 열린 시간을 수신하기 위한 배열
datetime temp[10];
CopyTime(Symbol(),Period(),time1,10,temp);
//--- 첫 번째 점에서 남은 9개 막대에 두 번째 점을 설정
time2=temp[0];
}
//--- 두 번째 점의 가격이 설정되지 않은 경우 첫 번째 점보다 300 포인트 낮게 이동합니다
if(!price2)
price2=price1-300*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- 세 번째 점의 시간이 설정되지 않은 경우 두 번째 점의 날짜와 일치합니다
if(!time3)
time3=time2;
//--- 세 번째 점의 가격이 정해지지 않은 경우 첫 번째 점의 가격과 일치합니다
if(!price3)
price3=price1;
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 입력 매개변수의 정확성 확인
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
{
Print("오류! 입력 매개변수의 잘못된 값!");
return;
}
//--- 차트 창에 표시되는 막대 수
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 가격 배열 크기
int accuracy=1000;
//--- 사용할 날짜 및 가격 값을 저장하기 위한 배열
//--- 타원 고정점의 좌표 설정 및 변경
datetime date[];
double price[];
//--- 메모리 할당
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 날짜 배열 채우기
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("시간 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 가격 배열 채우기
//--- 차트의 최고값과 최저값을 찾기
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 가격의 변경 단계를 정의 하고 배열 채우기
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 타원을 그리기 위한 점 지정
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
//--- 타원 생성
if(!EllipseCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
InpColor,InpStyle,InpWidth,InpFill,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- 차트를 다시 그리고 1초 동안 대기
ChartRedraw();
Sleep(1000);
//--- 이제 타원 고정점을 이동합니다
//--- 루프 카운터
int v_steps=accuracy/5;
//--- 첫 번째 및 두 번째 고정점 이동
for(int i=0;i<v_steps;i++)
{
//--- 다음의 값을 사용
if(p1<accuracy-1)
p1+=1;
if(p2>1)
p2-=1;
//--- 점 변경
if(!EllipsePointChange(0,InpName,0,date[d1],price[p1]))
return;
if(!EllipsePointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
}
//--- 1초 지연
Sleep(1000);
//--- 루프 카운터
int h_steps=bars/5;
//--- 세 번째 고정점 이동
for(int i=0;i<h_steps;i++)
{
//--- 다음의 값 사용
if(d3>1)
d3-=1;
//--- 점 이동
if(!EllipsePointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
// 0.05초 지연
Sleep(50);
}
//--- 1초 지연
Sleep(1000);
//--- 차트에서 타원 삭제
EllipseDelete(0,InpName);
ChartRedraw();
//--- 1초 지연
Sleep(1000);
//---
} |
