//--- 설명
#property description "스크립트는 \"수직선\" 그래픽 개체를 만들고 이동합니다."
#property description "고정점 날짜는 백분율로 설정됩니다."
#property description "차트 창 너비(막대 단위)."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpName="VLine"; // 선 이름
input int InpDate=25; // 이벤트 날짜(%)
input color InpColor=clrRed; // 선 색상
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // 선 스타일
input int InpWidth=3; // 선 너비
input bool InpBack=false; // 배경 선
input bool InpSelection=true; // 이동하려면 강조 표시
input bool InpRay=true; // 아래로 선 연장
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 수직선 생성 |
//+------------------------------------------------------------------+
bool VLineCreate(const long chart_ID=0, // 차트의 ID
const string name="VLine", // 선 이름
const int sub_window=0, // 하위 창 인덱스
datetime time=0, // 선 시간
const color clr=clrRed, // 선 색상
const ENUM_LINE_STYLE style=STYLE_SOLID, // 선 스타일
const int width=1, // 선 너비
const bool back=false, // 배경에
const bool selection=true, // 이동하려면 강조 표시
const bool ray=true, // 아래쪽으로 선 연장
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 선 시간이 설정되지 않은 경우 마지막 막대를 통해 그립니다
if(!time)
time=TimeCurrent();
//--- 오류 값 재설정
ResetLastError();
//--- 수직선 생성
if(!ObjectCreate(chart_ID,name,OBJ_VLINE,sub_window,time,0))
{
Print(__FUNCTION__,
": 수직선 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 선 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 선 표시 스타일 설정
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 선 굵기 설정
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 마우스를 사용하여 선을 이동하는 모드를 활성화(true) 또는 비활성화(false)
//--- ObjectCreate 함수를 사용하여 그래픽 개체를 만드는 경우 개체는
//--- 기본적으로 강조 표시되고 이동됩니다. 이 메서드 내에서 선택 매개변수
//--- 기본적으로 true이므로 개체를 강조 표시하고 이동할 수 있습니다.
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 차트 하위 창에 선 표시 모드 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_RAY,ray);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 수직선 이동 |
//+------------------------------------------------------------------+
bool VLineMove(const long chart_ID=0, // 차트의 ID
const string name="VLine", // 선 이름
datetime time=0) // 선 시간
{
//--- 선 시간이 설정되지 않은 경우 선을 마지막 막대로 이동합니다
if(!time)
time=TimeCurrent();
//--- 오류 값 재설정
ResetLastError();
//--- 수직선 이동
if(!ObjectMove(chart_ID,name,0,time,0))
{
Print(__FUNCTION__,
": 수직선 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 수직선 실패 |
//+------------------------------------------------------------------+
bool VLineDelete(const long chart_ID=0, // 차트의 ID
const string name="VLine") // 선 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 수직선 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": 수직선 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 입력 매개변수의 정확성 확인
if(InpDate<0 || InpDate>100)
{
Print("오류! 입력 매개변수의 잘못된 값!");
return;
}
//--- 차트 창에 표시되는 막대 수
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 사용할 날짜 값을 저장하기 위한 배열
//--- 선 고정점 좌표 설정 및 변경
datetime date[];
//--- 메모리 할당
ArrayResize(date,bars);
//--- 날짜 배열 채우기
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("시간 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 선을 그리기 위한 점 지정
int d=InpDate*(bars-1)/100;
//--- 수직선 생성
if(!VLineCreate(0,InpName,0,date[d],InpColor,InpStyle,InpWidth,InpBack,
InpSelection,InpRay,InpHidden,InpZOrder))
return;
//--- 차트를 다시 그리고 1초 동안 대기
ChartRedraw();
Sleep(1000);
//--- 이제 선을 이동합니다
//--- 루프 카운터
int h_steps=bars/2;
//--- 선 이동
for(int i=0;i<h_steps;i++)
{
//--- 다음의 값 사용
if(d<bars-1)
d+=1;
//--- 점 이동
if(!VLineMove(0,InpName,date[d]))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
// 0.03 초 지연
Sleep(30);
}
//--- 1초 지연
Sleep(1000);
//--- 차트에서 채널을 삭제
VLineDelete(0,InpName);
ChartRedraw();
//--- 1초 지연
Sleep(1000);
//---
} |
