//--- descripción
#property description "El script construye la elipse en el gráfico."
#property description "Las coordenadas de los puntos de anclaje se establecen"
#property description "en por cientos de las dimensiones de la ventana del gráfico."
//--- mostramos la ventana de los parámetros de entrada durante el arranque del script
#property script_show_inputs
//--- los parámetros de entrada del script
input string InpName="Ellipse"; // Nombre de la elipse
input int InpDate1=30; // Fecha del 1-er punto en %
input int InpPrice1=20; // Precio del 1-er punto en %
input int InpDate2=70; // Fecha del 2-do punto en %
input int InpPrice2=80; // Precio del 2-do punto en %
input int InpDate3=50; // Fecha del 3-er punto en %
input int InpPrice3=60; // Precio del 3-er punto en %
input color InpColor=clrRed; // Color de la elipse
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Estilo de las líneas de la elipse
input int InpWidth=2; // Grosor de las líneas de la elipse
input bool InpFill=false; // Relleno de la elipse con el color
input bool InpBack=false; // La elipse al fondo
input bool InpSelection=true; // Seleccionar para mover
input bool InpHidden=true; // Ocultar en la lista de objetos
input long InpZOrder=0; // Prioridad para el clic del ratón
//+------------------------------------------------------------------+
//| Crea la elipse según las coordenadas establecidas |
//+------------------------------------------------------------------+
bool EllipseCreate(const long chart_ID=0, // ID del gráfico
const string name="Ellipse", // nombre de la elipse
const int sub_window=0, // número de subventana
datetime time1=0, // hora del primer punto
double price1=0, // precio del primer punto
datetime time2=0, // hora del segundo punto
double price2=0, // precio del segundo punto
datetime time3=0, // hora del tercer punto
double price3=0, // precio del tercer punto
const color clr=clrRed, // color de la elipse
const ENUM_LINE_STYLE style=STYLE_SOLID, // estilo de las líneas de la elipse
const int width=1, // grosor de las líneas de la elipse
const bool fill=false, // relleno de la elipse con el color
const bool back=false, // al fondo
const bool selection=true, // seleccionar para mover
const bool hidden=true, // ocultar en la lista de objetos
const long z_order=0) // prioridad para el clic del ratón
{
//--- establecemos las coordenadas de los puntos de anclaje si todavía no han sido establecidas
ChangeEllipseEmptyPoints(time1,price1,time2,price2,time3,price3);
//--- anulamos el valor del error
ResetLastError();
//--- creamos la elipse según las coordenadas establecidas
if(!ObjectCreate(chart_ID,name,OBJ_ELLIPSE,sub_window,time1,price1,time2,price2,time3,price3))
{
Print(__FUNCTION__,
": ¡Fallo al crear la elipse! Código del error = ",GetLastError());
return(false);
}
//--- establecemos el color de la elipse
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- establecemos el estilo de las líneas de la elipse
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- establecemos el grosor de las líneas de la elipse
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- activar (true) o desactivar (false) el modo de relleno de la elipse
ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);
//--- mostramos en el primer plano (false) o al fondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- activar (true) o desactivar (false) el modo de selección de la elipse para mover
//--- cuando el objeto gráfico se crea usando la función ObjectCreate, por defecto el objeto
//--- no se puede seleccionar y mover. Mientras que dentro de este método el parámetro selection
//--- por defecto es igual a true, lo que permite seleccionar y mover este objeto
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ocultamos (true) o mostramos (false) el nombre del objeto gráfico en la lista de objetos
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- establecemos la prioridad para obtener el evento de cliquear sobre el gráfico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Mueve el punto de anclaje de la elipse |
//+------------------------------------------------------------------+
bool EllipsePointChange(const long chart_ID=0, // ID del gráfico
const string name="Ellipse", // nombre de la elipse
const int point_index=0, // número del punto de anclaje
datetime time=0, // coordenada del tiempo del punto de anclaje
double price=0) // coordenada del precio del punto de anclaje
{
//--- si las coordenadas del punto de anclaje no han sido establecidas, lo movemos a la barra actual con el precio Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- anulamos el valor del error
ResetLastError();
//--- movemos el punto de anclaje
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": ¡Fallo al mover el punto de anclaje! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Elimina la elipse |
//+------------------------------------------------------------------+
bool EllipseDelete(const long chart_ID=0, // ID del gráfico
const string name="Ellipse") // nombre de la elipse
{
//--- anulamos el valor del error
ResetLastError();
//--- eliminamos la elipse
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": ¡Fallo al eliminar la elipse! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Comprueba los valores de los puntos de anclaje de la elipse y para |
//| los valores vacíos establece los valores por defecto |
//+------------------------------------------------------------------+
void ChangeEllipseEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2,
datetime &time3,double &price3)
{
//--- si la hora del primer punto no ha sido establecida, se colocará en la barra actual
if(!time1)
time1=TimeCurrent();
//--- si el precio del primer punto no ha sido establecido, tendrá el valor Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- si la hora del segundo punto no ha sido establecida, se colocará a 9 barras a la izquierda del segundo
if(!time2)
{
//--- array para recibir la hora de apertura de las últimas 10 barras
datetime temp[10];
CopyTime(Symbol(),Period(),time1,10,temp);
//--- colocamos el segundo punto a 9 barras a la izquierda del primero
time2=temp[0];
}
//--- si el precio del segundo punto no ha sido establecido, lo moveremos a 300 puntos por debajo del primer punto
if(!price2)
price2=price1-300*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- si la hora del tercer punto no ha sido establecida, va a coincidir con la fecha del segundo punto
if(!time3)
time3=time2;
//--- si el precio del tercer punto no ha sido establecido, va a coincidir con el precio del primer punto
if(!price3)
price3=price1;
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- comprobamos si los parámetros de entrada son correctos
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
{
Print("¡Error. Los parámetros de entrada no son correctos!");
return;
}
//--- número de barras visibles en la ventana del gráfico
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- tamaño del array price
int accuracy=1000;
//--- arrays para guardar los valores de las fechas y precios que van a utilizarse
//--- para establecer y modificar las coordenadas de los puntos de anclaje de la elipse
datetime date[];
double price[];
//--- asignación de la memoria
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- llenamos el array de datos
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("¡Fallo al copiar el valor de la hora! Código del error = ",GetLastError());
return;
}
//--- llenamos el array de precios
//--- encontramos el valor máximo y mínimo del gráfico
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- determinamos el paso del cambio del precio y llenamos el array
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- definimos los puntos para trazar la elipse
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
//--- creamos la elipse
if(!EllipseCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
InpColor,InpStyle,InpWidth,InpFill,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redibujamos el gráfico y esperamos 1 segundo
ChartRedraw();
Sleep(1000);
//--- ahora vamos a mover los puntos de anclaje de la elipse
//--- contador del ciclo
int v_steps=accuracy/5;
//--- movemos el primero y el segundo punto de anclaje
for(int i=0;i<v_steps;i++)
{
//--- cogemos los siguientes valores
if(p1<accuracy-1)
p1+=1;
if(p2>1)
p2-=1;
//--- movemos los puntos
if(!EllipsePointChange(0,InpName,0,date[d1],price[p1]))
return;
if(!EllipsePointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- comprobamos si el trabajo del script ha sido finalizado forzosamente
if(IsStopped())
return;
//--- redibujamos el gráfico
ChartRedraw();
}
//--- retardo de 1 segundo
Sleep(1000);
//--- contador del ciclo
int h_steps=bars/5;
//--- movemos el tercer punto de anclaje
for(int i=0;i<h_steps;i++)
{
//--- cogemos el siguiente valor
if(d3>1)
d3-=1;
//--- movemos el punto
if(!EllipsePointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- comprobamos si el trabajo del script ha sido finalizado forzosamente
if(IsStopped())
return;
//--- redibujamos el gráfico
ChartRedraw();
// retardo de 0,05 segundo
Sleep(50);
}
//--- retardo de 1 segundo
Sleep(1000);
//--- eliminamos la elipse desde el gráfico
EllipseDelete(0,InpName);
ChartRedraw();
//--- retardo de 1 segundo
Sleep(1000);
//---
} |
