//--- descripción
#property description "El script construye el objeto gráfico \"Retícula de Gann\"."
#property description "Las coordenadas de los puntos de anclaje de la retícula se establecen en por cientos"
#property description "de las dimensiones de la ventana del gráfico."
//--- mostramos la ventana de los parámetros de entrada durante el arranque del script
#property script_show_inputs
//--- los parámetros de entrada del script
input string InpName="GannGrid"; // Nombre de la retícula
input int InpDate1=15; // Fecha del 1-er punto en %
input int InpPrice1=25; // Precio del 1-er punto en %
input int InpDate2=35; // Fecha del 2-do punto en %
input double InpScale=3.0; // Escala
input bool InpDirection=false; // Dirección del trend
input color InpColor=clrRed; // Color de la retícula
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Estilo de las líneas de la retícula
input int InpWidth=1; // Grosor de las líneas del abanico
input bool InpBack=false; // Retícula al fondo
input bool InpSelection=true; // Seleccionar para mover
input bool InpHidden=true; // Ocultar en la lista de objetos
input long InpZOrder=0; // Prioridad para el clic del ratón
//+------------------------------------------------------------------+
//| Crea la "Retícula de Gann" |
//+------------------------------------------------------------------+
bool GannGridCreate(const long chart_ID=0, // ID del gráfico
const string name="GannGrid", // nombre de la retícula
const int sub_window=0, // número de subventana
datetime time1=0, // hora del primer punto
double price1=0, // precio del primer punto
datetime time2=0, // hora del segundo punto
const double scale=1.0, // escala
const bool direction=true, // dirección del trend
const color clr=clrRed, // color de la retícula
const ENUM_LINE_STYLE style=STYLE_SOLID, // estilo de las líneas de la retícula
const int width=1, // grosor de las líneas de la retícula
const bool back=false, // al fondo
const bool selection=true, // seleccionar para mover
const bool hidden=true, // ocultar en la lista de objetos
const long z_order=0) // prioridad para el clic del ratón
{
//--- establecemos las coordenadas de los puntos de anclaje si todavía no han sido establecidas
ChangeGannGridEmptyPoints(time1,price1,time2);
//--- anulamos el valor del error
ResetLastError();
//--- creamos la "Retícula de Gann" según las coordenadas establecidas
if(!ObjectCreate(chart_ID,name,OBJ_GANNGRID,sub_window,time1,price1,time2,0))
{
Print(__FUNCTION__,
": ¡Fallo al crear la \"Retícula de Gann\"! Código del error = ",GetLastError());
return(false);
}
//--- cambiamos la escala (número de pips por barra)
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- cambiamos la dirección del trend de la "Retícula de Gann" (true - hacia abajo, false - para arriba)
ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction);
//--- establecemos el color de la retícula
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- establecemos el estilo de las líneas de la retícula
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- establecemos el grosor de las líneas de la retícula
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostramos en el primer plano (false) o al fondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- activar (true) o desactivar (false) el modo de selección de la retícula para mover
//--- cuando el objeto gráfico se crea usando la función ObjectCreate, por defecto el objeto
//--- no se puede seleccionar y mover. Mientras que dentro de este método el parámetro selection
//--- por defecto es igual a true, lo que permite seleccionar y mover este objeto
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ocultamos (true) o mostramos (false) el nombre del objeto gráfico en la lista de objetos
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- establecemos la prioridad para obtener el evento de cliquear sobre el gráfico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Mueve el punto de anclaje de la "Retícula de Gann" |
//+------------------------------------------------------------------+
bool GannGridPointChange(const long chart_ID=0, // ID del gráfico
const string name="GannGrid", // nombre de la retícula
const int point_index=0, // número del punto de anclaje
datetime time=0, // coordenada del tiempo del punto de anclaje
double price=0) // coordenada del precio del punto de anclaje
{
//--- si las coordenadas del punto de anclaje no han sido establecidas, lo movemos a la barra actual con el precio Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- anulamos el valor del error
ResetLastError();
//--- movemos el punto de anclaje de la retícula
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": ¡Fallo al mover el punto de anclaje! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Cambia la escala de la "Retícula de Gann" |
//+------------------------------------------------------------------+
bool GannGridScaleChange(const long chart_ID=0, // ID del gráfico
const string name="GannGrid", // nombre de la retícula
const double scale=1.0) // escala
{
//--- anulamos el valor del error
ResetLastError();
//--- cambiamos la escala (número de pips por barra)
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
{
Print(__FUNCTION__,
": ¡Fallo al cambiar la escala! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Cambia la dirección del trend de la "Retícula de Gann" |
//+------------------------------------------------------------------+
bool GannGridDirectionChange(const long chart_ID=0, // ID del gráfico
const string name="GannGrid", // nombre de la retícula
const bool direction=true) // dirección del trend
{
//--- anulamos el valor del error
ResetLastError();
//--- cambiamos la dirección del trend de la "Retícula de Gann"
if(!ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction))
{
Print(__FUNCTION__,
": ¡Fallo al cambiar la dirección del trend! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| La función elimina la "Retícula de Gann" desde el gráfico |
//+------------------------------------------------------------------+
bool GannGridDelete(const long chart_ID=0, // ID del gráfico
const string name="GannGrid") // nombre de la retícula
{
//--- anulamos el valor del error
ResetLastError();
//--- eliminamos la Retícula de Gann
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": ¡Fallo al eliminar la \"Retícula de Gann\"! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Comprueba los valores de los puntos de anclaje de la Retícula de Gann y para |
//| los valores vacíos establece los valores por defecto |
//+------------------------------------------------------------------+
void ChangeGannGridEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- si la hora del segundo punto no ha sido establecida, se colocará en la barra actual
if(!time2)
time2=TimeCurrent();
//--- si la hora del primer punto no ha sido establecida, se colocará a 9 barras a la izquierda del primero
if(!time1)
{
//--- array para recibir la hora de apertura de las últimas 10 barras
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- colocamos el primer punto a 9 barras a la izquierda del segundo
time1=temp[0];
}
//--- si el precio del primer punto no ha sido establecido, tendrá el valor Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- comprobamos si los parámetros de entrada son correctos
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("¡Error. Los parámetros de entrada no son correctos!");
return;
}
//--- número de barras visibles en la ventana del gráfico
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- tamaño del array price
int accuracy=1000;
//--- arrays para guardar los valores de las fechas y precios que van a utilizarse
//--- para establecer y modificar las coordenadas de los puntos de anclaje de la retícula
datetime date[];
double price[];
//--- asignación de la memoria
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- llenamos el array de datos
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("¡Fallo al copiar el valor de la hora! Código del error = ",GetLastError());
return;
}
//--- llenamos el array de precios
//--- encontramos el valor máximo y mínimo del gráfico
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- determinamos el paso del cambio del precio y llenamos el array
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- definimos los puntos para trazar la Retícula de Gann
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- creamos la Retícula de Gann
if(!GannGridCreate(0,InpName,0,date[d1],price[p1],date[d2],InpScale,InpDirection,
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redibujamos el gráfico y esperamos 1 segundo
ChartRedraw();
Sleep(1000);
//--- ahora vamos a mover los puntos de anclaje de la retícula
//--- contador del ciclo
int v_steps=accuracy/4;
//--- movemos el primer punto de anclaje verticalmente
for(int i=0;i<v_steps;i++)
{
//--- cogemos el siguiente valor
if(p1<accuracy-1)
p1+=1;
if(!GannGridPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- comprobamos si el trabajo del script ha sido finalizado forzosamente
if(IsStopped())
return;
//--- redibujamos el gráfico
ChartRedraw();
}
//--- retardo de 1 segundo
Sleep(1000);
//--- contador del ciclo
int h_steps=bars/4;
//--- movemos el segundo punto de anclaje por la horizontal
for(int i=0;i<h_steps;i++)
{
//--- cogemos el siguiente valor
if(d2<bars-1)
d2+=1;
if(!GannGridPointChange(0,InpName,1,date[d2],0))
return;
//--- comprobamos si el trabajo del script ha sido finalizado forzosamente
if(IsStopped())
return;
//--- redibujamos el gráfico
ChartRedraw();
// retardo de 0,05 segundo
Sleep(50);
}
//--- retardo de 1 segundo
Sleep(1000);
//--- cambiamos la dirección del trend de la retícula hacia abajo
GannGridDirectionChange(0,InpName,true);
//--- redibujamos el gráfico
ChartRedraw();
//--- retardo de 1 segundo
Sleep(1000);
//--- eliminamos la retícula desde el gráfico
GannGridDelete(0,InpName);
ChartRedraw();
//--- retardo de 1 segundo
Sleep(1000);
//---
} |
