//--- descrizione
#property description "Lo Script disegna l'oggetto grafico \"Ventaglio di Gann\"."
#property description "Le coordinate del punto di ancoraggio sono impostate in percentuale"
#property description " della grandezza della finestra chart."
//--- mostra la finestra dei parametri di input durante il lancio dello script
#property script_show_inputs
//--- parametri di input dello script
input string InpName="GannFan"; // Nome dell'oggetto
input int InpDate1=15; // data del 1mo punto, %
input int InpPrice1=25; // prezzo del 1mo punto, %
input int InpDate2=85; // data del 2ndo punto, %
input double InpScale=2.0; // Scala
input bool InpDirection=false; // Direzione del Trend
input color InpColor=clrRed; // Colore del Ventaglio
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Stile delle linee ventaglio
input int InpWidth=1; // Spessore delle linee ventaglio
input bool InpBack=false; // ventagli di sottofondo
input bool InpSelection=true; // Evidenzia movimento
input bool InpHidden=true; // Nascosto nella lista oggetti
input long InpZOrder=0; // Priorità per il click del mouse
//+--------------------------------------------------------------------------------+
//| Crea Ventaglio di Gann |
//+--------------------------------------------------------------------------------+
bool GannFanCreate(const long chart_ID=0, // ID del chart
const string name="GannFan", // nome del ventaglio
const int sub_window=0, // indice sottofinestra
datetime time1=0, // orario del primo punto
double price1=0, // prezzo del primo punto
datetime time2=0, // orario del secondo punto
const double scale=1.0, // scala
const bool direction=true, // direzione del trend
const color clr=clrRed, // colore ventaglio
const ENUM_LINE_STYLE style=STYLE_SOLID, // stile delle linee ventaglio
const int width=1, // spessore delle linee ventaglio
const bool back=false, // in sottofondo
const bool selection=true, // evidenzia movimento
const bool hidden=true, // nascosto nella lista oggetti
const long z_order=0) // priorità per il click del mouse
{
//--- imposta coordinate punto di ancoraggio se non sono impostate
ChangeGannFanEmptyPoints(time1,price1,time2);
//--- resetta il valore dell' errore
ResetLastError();
//--- create Gann Fan by the given coordinates
if(!ObjectCreate(chart_ID,name,OBJ_GANNFAN,sub_window,time1,price1,time2,0))
{
Print(__FUNCTION__,
": fallimento nel creare il \"Ventaglio di Gann\"! Error code = ",GetLastError());
return(false);
}
//--- cambia la scala (numero di pips per barra)
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- cambia la direzione del trend del Ventaglio di Gann (true - discendente, false - ascendente)
ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction);
//--- imposta il colore del ventaglio
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- imposta lo stile della visualizzazione delle linee del ventaglio
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- imposta lo spessore delle linee del ventaglio
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostra in primo piano (false) o sottofondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- abilita (true) o disabilita (false) la modalità di evidenzia del venglio per lo spostamento
//--- quando si crea un oggetto grafico utilizzando la funzione ObjectCreate, l'oggetto non può esser
//--- evidenziato e mosso, per default. All'interno di questo metodo, la selezione dei parametri
//--- è true per default, il che consente di evidenziare e spostare l'oggetto
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- nascondi (true) o mostra (falso) il nome di oggetto grafico nella lista degli oggetti
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- imposta la priorità per ricevere l'evento di un clic del mouse nel grafico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Sposta il punto di ancoraggio del Ventaglio di Gann |
//+--------------------------------------------------------------------------------+
bool GannFanPointChange(const long chart_ID=0, // ID del chart
const string name="GannFan", // nome del ventaglio
const int point_index=0, // indice del punto di ancoraggio
datetime time=0, // coordinate del punto di ancoraggio tempo
double price=0) // coordinate prezzo, del punto di ancoraggio
{
//--- se il punto della posizione non è impostato, spostarlo nella barra corrente che ha il prezzo Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- resetta il valore dell' errore
ResetLastError();
//--- sposta il punto di ancoraggio del ventaglio
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": fallimento nello spostare il punto di ancoraggio! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Cambia la scala del Ventaglio di Gann |
//+--------------------------------------------------------------------------------+
bool GannFanScaleChange(const long chart_ID=0, // ID del chart
const string name="GannFan", // nome del ventaglio
const double scale=1.0) // scala
{
//--- resetta il valore dell' errore
ResetLastError();
//--- cambia la scala (numero di pips per barra)
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
{
Print(__FUNCTION__,
": fallimento nel cambiare la scala! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Cambia la direzione del trend del Ventaglio di Gann |
//+--------------------------------------------------------------------------------+
bool GannFanDirectionChange(const long chart_ID=0, // ID del chart
const string name="GannFan", // nome del ventaglio
const bool direction=true, // direzione del trend
{
//--- resetta il valore dell' errore
ResetLastError();
//--- cambia la direzione del trend del Ventaglio di Gann
if(!ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction))
{
Print(__FUNCTION__,
": fallimento nel cambiare la direzione del trend! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| La funzione rimuove il Ventaglio di Gann dal chart |
//+--------------------------------------------------------------------------------+
bool GannFanDelete(const long chart_ID=0, // ID del chart
const string name="GannFan", // nome del ventaglio
{
//--- resetta il valore dell' errore
ResetLastError();
//--- elimina il Ventaglio di Gann
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": fallimento nell'eliminare il \"Ventaglio di Gann\"! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Controlla i valori dei punti di ancoraggio degli del Ventaglio di Gann ed imposta i |
//| valori di default per quelli vuoti |
//+--------------------------------------------------------------------------------+
void ChangeGannFanEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- se l'orario del secondo punto non è impostato, sarà sulla barra corrente
if(!time2)
time2=TimeCurrent();
//--- se l'orario del primo punto non è impostato, è posizionato 9 barre meno dalla seconda
if(!time1)
{
//--- array per la ricezione dell'orario di apertura delle ultime 10 barre
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- imposta il primo punto 9 barre a sinistra dalla seconda
time1=temp[0];
}
//--- se il prezzo del punto non è impostato, avrà un valore Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script |
//+--------------------------------------------------------------------------------+
voidOnStart()
{
//--- imposta la correttezza dei parametri di input
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Error! Valori non corretti dei parametri di input!");
return;
}
//--- Numero di barre visibili nella finestra del chart
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- grandezza dell'array prezzo
int accuracy=1000;
//--- array per la memorizzazione dei valori di data e prezzo da essere usati
//--- per impostare e cambiare le coordinate dei punti di ancoraggio del Ventaglio
datetime date[];
double price[];
//--- allocazione della memoria
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- riempie l'array delle date
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Fallimento nella copia dei valori tempo! Error code = ",GetLastError());
return;
}
/--- riempie l'array dei prezzi
//--- trova i valori più alti e più bassi del chart
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- definisce un cambio di step del prezzo e riempie l'array
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- definisce i punti per disegnare il Ventaglio di Gann
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- crea il Ventaglio di Gann
if(!GannFanCreate(0,InpName,0,date[d1],price[p1],date[d2],InpScale,InpDirection,
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redisegna il chart ed attende per 1 secondo
ChartRedraw();
Sleep(1000);
//--- ora, sposta i punti di ancoraggio del ventaglio
//---contatore del ciclo
int v_steps=accuracy/2;
//--- sposta il primo punto di ancoraggio, verticalmente
for(int i=0;i<v_steps;i++)
{
//--- usa il seguente valore
if(p1<accuracy-1)
p1+=1;
//--- sposta il punto
if(!GannFanPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
}
//--- 1 secondo di ritardo
Sleep(1000);
//--- cambia la direzione del trend del Ventaglio in discendente
GannFanDirectionChange(0,InpName,true);
//--- redisegna il chart
ChartRedraw();
//--- 1 secondo di ritardo
Sleep(1000);
//--- elimina il ventaglio dal chart
GannFanDelete(0,InpName);
ChartRedraw();
//--- 1 secondo di ritardo
Sleep(1000);
//---
} |
