//--- descrizione
#property description "Lo Script disegna segni \"Buy\" nella finestra chart."
//--- mostra la finestra dei parametri di input durante il lancio dello script
#property script_show_inputs
//--- parametri di input dello script
input color InpColor=C'3,95,172'; // Colore dei segni
//+--------------------------------------------------------------------------------+
//| Crea il segno Buy |
//+--------------------------------------------------------------------------------+
bool ArrowBuyCreate(const long chart_ID=0, // ID del chart
const string name="ArrowBuy", // nome del segno
const int sub_window=0, // indice sottofinestra
datetime time=0, // orario del punto di ancoraggio
double price=0, // prezzo del punto di ancoraggio
const color clr=C'3,95,172', // colore del segno
const ENUM_LINE_STYLE style=STYLE_SOLID, // stile linea (quando evidenziata)
const int width=1, // spessore linea (quando evidenziata)
const bool back=false, // in sottofondo
const bool selection=false, // evidenziazione di spostamento
const bool hidden=true, // nascosta nella lista oggetti
const long z_order=0) // priorità per il click del mouse
{
//--- imposta coordinate punto di ancoraggio se non sono impostate
ChangeArrowEmptyPoint(time,price);
//--- resetta il valore dell' errore
ResetLastError();
//--- crea il segno
if(!ObjectCreate(chart_ID,name,OBJ_ARROW_BUY,sub_window,time,price))
{
Print(__FUNCTION__,
": fallimento nella creazione del segno \"Buy\"! Error code = ",GetLastError());
return(false);
}
//--- imposta il colore del segno
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- imposta lo stile della linea (quando evidenziata)
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- imposta la grandezza della linea (quando evidenziata)
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostra in primo piano (false) o sottofondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- abilita (true) o disabilita (false) la modalità di spostare il segno con il mouse
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- nascondi (true) o mostra (falso) il nome di oggetto grafico nella lista degli oggetti
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- imposta la priorità per ricevere l'evento di un clic del mouse nel grafico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Sposta il punto di ancoraggio |
//+--------------------------------------------------------------------------------+
bool ArrowBuyMove(const long chart_ID=0, // ID del chart
const string name="ArrowBuy", // object name
datetime time=0, // coordinate tempo, del punto di ancoraggio
double price=0) // coordinate prezzo, del punto di ancoraggio
{
//--- se il punto della posizione non è impostato, spostarlo nella barra corrente che ha il prezzo Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- resetta il valore dell' errore
ResetLastError();
//--- sposta il punto di ancoraggio
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": fallimento nello spostare il punto di ancoraggio! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Elimina il segno di Buy |
//+--------------------------------------------------------------------------------+
bool ArrowBuyDelete(const long chart_ID=0, // ID del chart
const string name="ArrowBuy") // nome del segno
{
//--- resetta il valore dell' errore
ResetLastError();
//--- elimina il segno
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": fallimento nell'eliminazione del segno \"Buy\"! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Controlla i valori di punto di ancoraggio ed imposta i valori di default |
//| per quelli vuoti |
//+--------------------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- se il tempo del punto non è impostato, sarà sulla barra corrente
if(!time)
time=TimeCurrent();
//--- se il prezzo del punto non è impostato, avrà un valore Bid
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script |
//+--------------------------------------------------------------------------------+
voidOnStart()
{
datetime date[]; // array per memorizzare le date di barre visibili
double low[]; // array per memorizzare i prezzi Low delle barre visibili
double high[]; // array memorizzare i prezzi High di barre visibili
//--- Numero di barre visibili nella finestra del chart
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- allocazione della memoria
ArrayResize(date,bars);
ArrayResize(low,bars);
ArrayResize(high,bars);
//--- riempie l'array delle date
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Fallimento nella copia dei valori tempo! Error code = ",GetLastError());
return;
}
//--- riempie l'array dei prezzi Low
if(CopyLow(Symbol(),Period(),0,bars,low)==-1)
{
Print("Fallimento nel copiare i valori dei prezzi Low! Error code = ",GetLastError());
return;
}
//--- riempie l'array di prezzi High
if(CopyHigh(Symbol(),Period(),0,bars,high)==-1)
{
Print("Fallimento nel copiare i valori dei prezzi High! Error code = ",GetLastError());
return;
}
//--- creare i segni Buy nel punto Low per ogni barra visibile
for(int i=0;i<bars;i++)
{
if(!ArrowBuyCreate(0,"ArrowBuy_"+(string)i,0,date[i],low[i],InpColor))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
// 0.05 secondi di ritardo
Sleep(50);
}
//--- sposta i segni Buy signs al punto High per ogni barra visibile
for(int i=0;i<bars;i++)
{
if(!ArrowBuyMove(0,"ArrowBuy_"+(string)i,date[i],high[i]))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
// 0.05 secondi di ritardo
Sleep(50);
}
//--- elimina i segni Buy
for(int i=0;i<bars;i++)
{
if(!ArrowBuyDelete(0,"ArrowBuy_"+(string)i))
return;
//--- ridisegna il chart
ChartRedraw();
// 0.05 secondi di ritardo
Sleep(50);
}
//---
} |
