//--- descrizione
#property description "Script draws \"Equidistant Channel\" oggetto grafico."
#property description "Le coordinate del punto di ancoraggio sono impostate in percentuale della grandezza della"
#property description "finestra del chart."
//--- mostra la finestra dei parametri di input durante il lancio dello script
#property script_show_inputs
//--- parametri di input dello script
input string InpName="Channel"; // Nome del canale
input int InpDate1=25; // data del 1mo punto, %
input int InpPrice1=60; // Prezzo del 1mo punto, in%
input int InpDate2=65; // data del 2ndo punto, %
input int InpPrice2=80; // prezzo del 2ndo punto, %
input int InpDate3=30; // data del 3zo punto, %
input int InpPrice3=40; // prezzo del 3zo punto, %
input color InpColor=clrRed; // Colore del canale
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Stile delle linee del canale
input int InpWidth=2; // Spessore della linea del canale
input bool InpBack=false; // Canale di sottofondo
input bool InpFill=false; // Riempie il canale con colore
input bool InpSelection=true; // Evdenzia movimento
input bool InpRayLeft=false; // Continuazione del canale a sinistra
input bool InpRayRight=false; // Continuazione del canale a destra
input bool InpHidden=true; // Nascosto nella lista oggetti
input long InpZOrder=0; // Priorità per il click del mouse
//+--------------------------------------------------------------------------------+
//| Crea un canale equidistante dalle coordinate date |
//+--------------------------------------------------------------------------------+
bool ChannelCreate(const long chart_ID=0, // ID del chart
const string name="Channel", // nome del canale
const int sub_window=0, // indice sottofinestra
datetime time1=0, // orario del primo punto
double price1=0, // prezzo del primo punto
datetime time2=0, // orario del secondo punto
double price2=0, // prezzo del secondo punto
datetime time3=0, // orario del terzo punto
double price3=0, // prezzo del terzo punto
const color clr=clrRed, // colore del canale
const ENUM_LINE_STYLE style=STYLE_SOLID, // stile delle linee del canale
const int width=1, // spesso delle linee del canale
const bool fill=false, // riempimento del canale con colore
const bool back=false, // in sottofondo
const bool selection=true, // evidenzia movimento
const bool ray_left=false, // continua del canale a sinistra
const bool ray_right=false, // continua del canale a destra
const bool hidden=true, // nascosto nella lista oggetti
const long z_order=0) // priorità per il click del mouse
{
//--- imposta coordinate punto di ancoraggio se non sono impostate
ChangeChannelEmptyPoints(time1,price1,time2,price2,time3,price3);
//--- resetta il valore dell' errore
ResetLastError();
//--- crea il canale dalle coordinate date
if(!ObjectCreate(chart_ID,name,OBJ_CHANNEL,sub_window,time1,price1,time2,price2,time3,price3))
{
Print(__FUNCTION__,
": fallimento nel creare il canale equidistante! Error code = ",GetLastError());
return(false);
}
//--- imposta il colore del canale
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- imposta lo stile delle linee del canale
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- imposta lo spessore delle linee del canale
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- abilita (true) o disabilita (false) la modalità di riempimento del canale
ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);
//--- mostra in primo piano (false) o sottofondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- abilita (true) o disabilita (false) la modalità di evidenzia del canale per lo spostamento
//--- quando si crea un oggetto grafico utilizzando la funzione ObjectCreate, l'oggetto non può esser
//--- evidenziato e mosso, per default. All'interno di questo metodo, la selezione dei parametri
//--- è true per default, il che consente di evidenziare e spostare l'oggetto
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- abilita (true) o disabilita (false) la modalità di continuazione del display del canale a sinistra
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- abilita (true) o disabilita (false) la modalità di continuazione del display del canale a destra
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- nascondi (true) o mostra (falso) il nome di oggetto grafico nella lista degli oggetti
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- imposta la priorità per ricevere l'evento di un clic del mouse nel grafico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Sposta il punto di ancoraggio del canale |
//+--------------------------------------------------------------------------------+
bool ChannelPointChange(const long chart_ID=0, // ID del chart
const string name="Channel", // nome del canale
const int point_index=0, // indice del punto di ancoraggio
datetime time=0, // coordinate del punto di ancoraggio tempo
double price=0) // coordinate prezzo, del punto di ancoraggio
{
//--- se il punto della posizione non è impostato, spostarlo nella barra corrente che ha il prezzo Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- resetta il valore dell' errore
ResetLastError();
//--- sposta il punto di ancoraggio
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": fallimento nello spostare il punto di ancoraggio! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Elimina il canale |
//+--------------------------------------------------------------------------------+
bool ChannelDelete(const long chart_ID=0, // ID del chart
const string name="Channel") // nome del canale
{
//--- resetta il valore dell' errore
ResetLastError();
//--- elimina il canale
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": fallimento nell'eliminare il canale! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+---------------------------------------------------------------------------------------+
//| Controlla i valori dei punti di ancoraggio del canale ed impostare i valori di default|
//| per quelli vuoti |
//+---------------------------------------------------------------------------------------+
void ChangeChannelEmptyPoints(datetime &time1,double &price1,datetime &time2,
double &price2,datetime &time3,double &price3)
{
//--- se l'orario del secondo(destro) punto non è impostato, sarà sulla barra corrente
if(!time2)
time2=TimeCurrent();
//--- se il prezzo del secondo punto non è impostato, avrà un valore Bid
if(!price2)
price2=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- se l'orario del primo(sinistro) punto non è impostato, è posizionato 9 barre meno dalla seconda
if(!time1)
{
//--- array per la ricezione dell'orario di apertura delle ultime 10 barre
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- imposta il primo punto 9 barre a sinistra dalla seconda
time1=temp[0];
}
//--- se il prezzo del primo punto non è impostato, lo sposta di 300 punti in più rispetto al secondo
if(!price1)
price1=price2+300*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- se l'orario del terzo punto non è impostato, esso coincide con quello del primo punto
if(!time3)
time3=time1;
//--- se il prezzo del terzo punto non è impostato, è uguale a quello del secondo punto
if(!price3)
price3=price2;
}
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script |
//+--------------------------------------------------------------------------------+
voidOnStart()
{
//--- imposta la correttezza dei parametri di input
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
{
Print("Error! Valori non corretti dei parametri di input!");
return;
}
//--- Numero di barre visibili nella finestra del chart
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- grandezza dell'array prezzo
int accuracy=1000;
//--- array per la memorizzazione dei valori di data e prezzo da essere usati
//--- per impostare e modificare le coordinate dei punti di ancoraggio del canale"
datetime date[];
double price[];
//--- allocazione della memoria
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- riempie l'array delle date
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Fallimento nella copia dei valori tempo! Error code = ",GetLastError());
return;
}
/--- riempie l'array dei prezzi
//--- trova i valori più alti e più bassi del chart
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- definisce un cambio di step del prezzo e riempie l'array
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- definisce i punti per disegnare il canale
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
//--- crea il canale equidistante
if(!ChannelCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],InpColor,
InpStyle,InpWidth,InpFill,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- redisegna il chart ed attende per 1 secondo
ChartRedraw();
Sleep(1000);
//--- ora, sposta i punti di ancoraggio del canale
//---contatore del ciclo
int h_steps=bars/6;
//--- sposta il secondo punto di ancoraggio
for(int i=0;i<h_steps;i++)
{
//--- usa il seguente valore
if(d2<bars-1)
d2+=1;
//--- sposta il punto
if(!ChannelPointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
// 0.05 secondi di ritardo
Sleep(50);
}
//--- 1 secondo di ritardo
Sleep(1000);
//--- move the first anchor point
for(int i=0;i<h_steps;i++)
{
//--- usa il seguente valore
if(d1>1)
d1-=1;
//--- sposta il punto
if(!ChannelPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
// 0.05 secondi di ritardo
Sleep(50);
}
//--- 1 secondo di ritardo
Sleep(1000);
//---contatore del ciclo
int v_steps=accuracy/10;
//--- sposta il terzo punto di ancoraggio
for(int i=0;i<v_steps;i++)
{
//--- usa il seguente valore
if(p3>1)
p3-=1;
//--- sposta il punto
if(!ChannelPointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
}
//--- 1 secondo di ritardo
Sleep(1000);
//--- elimina il canale dal chart
ChannelDelete(0,InpName);
ChartRedraw();
//--- 1 secondo di ritardo
Sleep(1000);
//---
} |
