MQL5 リファレンス文字列関数StringAdd

StringAdd

이 함수는 문자열 끝에 하위 문자열을추가합니다.

bool  StringAdd(
   string&  string_var,        // 추가할 문자열
   string   add_substring      // 추가할 문자열
   );

Parameter

string_var

[in][out] 추가할 다른 문자열.

add_substring

[in] 소스 문자열 끝에 추가할 문자열.

반환값

성공 시 true를 반환하고, 그렇지 않으면 false를 반환합니다. 오류 코드를 얻으려면, GetLastError() 함수를 호출해야 합니다.

예:

void OnStart()
  {
   long length=1000000;
   string a="a",b="b",c;
//--- 첫번째 메소드
   uint start=GetTickCount(),stop;
   long i;
   for(i=0;i<length;i++)
     {
      c=a+b;
     }
   stop=GetTickCount();
   Print("time for 'c = a + b' = ",(stop-start)," milliseconds, i = ",i);

//--- 두번째 메소드
   start=GetTickCount();
   for(i=0;i<length;i++)
     {
      StringAdd(a,b);
     }
   stop=GetTickCount();
   Print("time for 'StringAdd(a,b)' = ",(stop-start)," milliseconds, i = ",i);

//--- 세번째 메소드
   start=GetTickCount();
   a="a"; // re-initialize variable a
   for(i=0;i<length;i++)
     {
      StringConcatenate(c,a,b);
     }
   stop=GetTickCount();
   Print("time for 'StringConcatenate(c,a,b)' = ",(stop-start)," milliseconds, i = ",i);
  }

참고 항목

StringConcatenate, StringSplit, StringSubstr

文字列関数

StringBufferLen