MQL5 リファレンス売買シグナルSignalBaseSelect

SignalBaseSelect

시그널들 중에서 한 시그널을 선택합니다. 시그널로 추가 작업을 위해 터미널에서 사용할 수 있습니다.

bool  SignalBaseSelect(
   int     index     // 시그널 인덱스
   );

Parameter

index

[in] 트레이딩 시그널 기준 시그널 인덱스.

반환값

성공하면 true를 반환하고 그렇지 않으면 false를 반환합니다. 에러에 대한 자세한 내용은 GetLastError()를 참조하십시오.

예:

void OnStart()
  {
//--- 터미널의 총 시그널 양을 수신
   int total=SignalBaseTotal();
//--- 모든 시그널 처리
   for(int i=0;i<total;i++)
     {
      //--- 인덱스로 시그널 선택
      if(SignalBaseSelect(i))
        {
         //--- 시그널 속성 취득
         long   id    =SignalBaseGetInteger(SIGNAL_BASE_ID);          // 시그널 id
         long   pips  =SignalBaseGetInteger(SIGNAL_BASE_PIPS);        // 핍(pip) 수익
         long   subscr=SignalBaseGetInteger(SIGNAL_BASE_SUBSCRIBERS); // 구독자 수
         string name  =SignalBaseGetString(SIGNAL_BASE_NAME);         // 시그널명
         double price =SignalBaseGetDouble(SIGNAL_BASE_PRICE);        // 시그널 가격
         string curr  =SignalBaseGetString(SIGNAL_BASE_CURRENCY);     // 시그널 통화
         //--- 모든 수익성 있는 무료 시그널을 구독자에게 출력
         if(price==0.0 && pips>0 && subscr>0)
            PrintFormat("id=%d, name=\"%s\", currency=%s, pips=%d, subscribers=%d",id,name,curr,pips,subscr);
        }
      else PrintFormat("SignalBaseSelect 요청 중 에러. Error code=%d",GetLastError());
     }
  }

SignalBaseGetString

SignalBaseTotal