//+--------------------------------------------------------------------------------+
//| Demo_FileWrite.mq5 |
//| Copyright 2013, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+--------------------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.00"
//--- mostra la finestra dei parametri di input quando si lancia lo script
#property script_show_inputs
//--- parametri per la ricezione dei dati dal terminale
input string InpSymbolName="EURUSD"; // coppia di valute
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_H1; // time frame
input int InpFastEMAPeriod=12; // periodo EMA veloce
input int InpSlowEMAPeriod=26; // periodo EMA lento
input int InpSignalPeriod=9; // differenza tra periodi di media
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE; // tipo di prezzo
input datetime InpDateStart=D'2012.01.01 00:00'; // data di inzio copiatura dati
//--- parametri per scrivere i dati nel file
input string InpFileName="MACD.csv"; // nome file
input string InpDirectoryName="Data"; // nome directory
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script |
//+--------------------------------------------------------------------------------+
voidOnStart()
{
datetime date_finish; // data di fine copiatura dati
bool sign_buff[]; // array signal (true - buy, false - sell)
datetime time_buff[]; // array dell'orario di arrivo di signal
int sign_size=0; // grandezza array signal
double macd_buff[]; // array dei valori indicatore
datetime date_buff[]; // array date indicatore
int macd_size=0; // grandezza array indicatore
//--- orario di fine è l'ora corrente
date_finish=TimeCurrent();
//--- riceve l'handle dell'indicatore MACD
ResetLastError();
int macd_handle=iMACD(InpSymbolName,InpSymbolPeriod,InpFastEMAPeriod,InpSlowEMAPeriod,InpSignalPeriod,InpAppliedPrice);
if(macd_handle==INVALID_HANDLE)
{
//--- fallimento nel ricevere l'handle indicatore
PrintFormat("Errore quando si è ricevuto l'handle indicatore. Codice Errore = %d",GetLastError());
return;
}
//--- essendo nel ciclo finché l'indicatore calcola tutti i valori
while(BarsCalculated(macd_handle)==-1)
Sleep(10); // pausa per consentire all'indicatore di calcolare tutti i suoi valori
//--- copia i valori dell'indicatore per un certo periodo di tempo
ResetLastError();
if(CopyBuffer(macd_handle,0,InpDateStart,date_finish,macd_buff)==-1)
{
PrintFormat("Fallimento nel copiare i valori indicatore. Codice Errore = %d",GetLastError());
return;
}
//--- copia l'orario appropriato per i valori indicatore
ResetLastError();
if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,date_buff)==-1)
{
PrintFormat("Fallimento nel copiare i valori temporali. Codice Errore = %d",GetLastError());
return;
}
//--- libera la memoria occupata per l'indicatore
IndicatorRelease(macd_handle);
//--- riceve la grandezza del buffer
macd_size=ArraySize(macd_buff);
//--- analizza i dati e salva i segnali indicatore nell'array
ArrayResize(sign_buff,macd_size-1);
ArrayResize(time_buff,macd_size-1);
for(int i=1;i<macd_size;i++)
{
//--- segnale buy
if(macd_buff[i-1]<0 && macd_buff[i]>=0)
{
sign_buff[sign_size]=true;
time_buff[sign_size]=date_buff[i];
sign_size++;
}
//--- segnale sell
if(macd_buff[i-1]>0 && macd_buff[i]<=0)
{
sign_buff[sign_size]=false;
time_buff[sign_size]=date_buff[i];
sign_size++;
}
}
//--- apre il file per la scrittura dei valori indicatore (se il file è assente, verrà creato automaticamente)
ResetLastError();
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_CSV);
if(file_handle!=INVALID_HANDLE)
{
PrintFormat("il file %s è disponibile per la scrittura",InpFileName);
PrintFormat("Percorso file: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
//--- prima, scrive il numero di segnali
FileWrite(file_handle,sign_size);
//--- scrive l'orario ed i valori dei segnali al file
for(int i=0;i<sign_size;i++)
FileWrite(file_handle,time_buff[i],sign_buff[i]);
//--- chiude il file
FileClose(file_handle);
PrintFormat("I dati vengono scritti, il file %s è chiuso",InpFileName);
}
else
PrintFormat("Fallimento nell'aprire il file %s, Codice errore = %d",InpFileName,GetLastError());
} |