Visibilità degli oggetti

voidOnStart()
  {
//---
   string highlevel="PreviousDayHigh";
   string lowlevel="PreviousDayLow";
   double prevHigh;           // Il Massimo(High) del giorno precedente
   double prevLow;            // Il Minimo(Low) del giorno precedente
   double highs[],lows[];     // Array per Massimo e Minimo
 
//--- Resetta l'ultimo errore
   ResetLastError();
//--- Riceve gli ultimi 2 valori Massimi sul timeframe giornaliero
   int highsgot=CopyHigh(Symbol(),PERIOD_D1,0,2,highs);
   if(highsgot>0) // Se la copia ha avuto successo
     {
      Print("I prezzi Massimi per gli ultimi 2 giorni sono stati ottenuti con successo");
      prevHigh=highs[0]; // Il Massimo(High) del giorno precedente
      Print("prevHigh = ",prevHigh);
      if(ObjectFind(0,highlevel)<0) // Oggetto con il nome highlevel non trovato
        {
         ObjectCreate(0,highlevel,OBJ_HLINE,0,0,0); // Crea l'oggetto Linea Orizzontale
        }
      //--- Imposta il valore per il livello del prezzo per la linea highlevel
      ObjectSetDouble(0,highlevel,OBJPROP_PRICE,0,prevHigh);
      //--- Imposta la visibilità solo per PERIOD_M10 e PERIOD_H4
      ObjectSetInteger(0,highlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else
     {
      Print("Non posso ottenere i prezzi Massimi(High) per gli ultimi 2 giorni, Errore = ",GetLastError());
     }
 
//--- Resetta l'ultimo errore
   ResetLastError();
//--- Ottiene i valori Minimi(Low) di 2 giorni sul timeframe giornaliero
   int lowsgot=CopyLow(Symbol(),PERIOD_D1,0,2,lows);
   if(lowsgot>0) // Se la copia ha avuto successo
     {
      Print("I prezzi Minimi(Low) per gli ultimi 2 giorni sono stati ottenuti con successo");
      prevLow=lows[0]; // Il Minimo del giorno precedente
      Print("prevLow = ",prevLow);
      if(ObjectFind(0,lowlevel)<0) // Oggetto con il nome lowlevel non trovato
        {
         ObjectCreate(0,lowlevel,OBJ_HLINE,0,0,0); // Crea l'oggetto Linea Orizzontale
        }
      //--- Imposta il valore per il livello del prezzo per la linea lowlevel
      ObjectSetDouble(0,lowlevel,OBJPROP_PRICE,0,prevLow);
      //--- Imposta la visibilità solo per PERIOD_M10 e PERIOD_H4
      ObjectSetInteger(0,lowlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
     }
   else Print("Non posso ottenere i prezzi Minimi(Low) per gli ultimi 2 giorni, Errore = ",GetLastError());
 
   ChartRedraw(0); // aggiorna il grafico forzatamente
  }