MathArccosh

double  MathArccosh(
   double  value     // 1 <= valeur < ∞
   );

#define GRAPH_WIDTH  750
#define GRAPH_HEIGHT 350
 
#include <Graphics\Graphic.mqh>
 
CGraphic ExtGraph;
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   vector delta=vector::Full(101,2*M_PI/10);
   delta[0]=1;
//--- prends 101 valeurs de 1 à 2 pi avec un pas de delta
   vector X=delta.CumSum();
//--- calcule la valeur du cosinus de l'arc hyperbolique pour chaque valeur du vecteur X
   vector Y=MathArccosh(X);
 
//--- transfére les valeurs calculées des vecteurs dans les tableaux
   double x_array[],y_array[];
   X.Swap(x_array);
   Y.Swap(y_array);
 
//--- dessine un graphique des valeurs vectorielles calculées
   CurvePlot(x_array,y_array,clrDodgerBlue);
 
//--- attend l'appui sur les touches Escape ou PgDn pour supprimer le graphique (prendre une capture d'écran) et quitter
   while(!IsStopped())
     {
      if(StopKeyPressed())
         break;
      Sleep(16);
     }
 
//--- nettoyage
   ExtGraph.Destroy();
  }
//+------------------------------------------------------------------+
//| si appui sur ESC, retourne 'vrai'                                |
//| Si appui sur PgDn, prends une capture d'écran et retourne 'true' |
//| Sinon, retourne 'false'                                          |
//+------------------------------------------------------------------+
bool StopKeyPressed()
  {
//--- si ESC est enfoncé, renvoie 'true'
   if(TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)!=0)
      return(true);
//--- si PgDn est enfoncé et qu'une capture d'écran graphique est prise avec succès, renvoie 'true'
   if(TerminalInfoInteger(TERMINAL_KEYSTATE_PAGEDOWN)!=0 && MakeAndSaveScreenshot(MQLInfoString(MQL_PROGRAM_NAME)+"_Screenshot"))
      return(true);
//--- retourne 'false'
   return(false);
  }
//+------------------------------------------------------------------+
//| Crée un objet graphique et dessine une courbe                    |
//+------------------------------------------------------------------+
void CurvePlot(double &x_array[], double &y_array[], const color colour)
  {
   ExtGraph.Create(ChartID(), "Graphic", 0, 0, 0, GRAPH_WIDTH, GRAPH_HEIGHT);
   ExtGraph.CurveAdd(x_array, y_array, ColorToARGB(colour), CURVE_LINES);
   ExtGraph.IndentUp(30);
   ExtGraph.CurvePlotAll();
   string text1="Press ESC to delete the graph and stop the script, or";
   string text2="Press PgDn to create a screen, delete the graph and stop the script";
   ExtGraph.TextAdd(54, 9, text1, ColorToARGB(clrBlack));
   ExtGraph.TextAdd(54,21, text2, ColorToARGB(clrBlack));
   ExtGraph.Update();
  }
//+------------------------------------------------------------------+
//| Prend une capture d'écran et l'enregistrer dans un fichier       |
//+------------------------------------------------------------------+
bool MakeAndSaveScreenshot(const string file_name)
  {
   string file_names[];
   ResetLastError();
   int selected=FileSelectDialog("Save Picture", NULL, "All files (*.*)|*.*", FSD_WRITE_FILE, file_names, file_name+".png");
   if(selected<1)
     {
      if(selected<0)
         PrintFormat("%s: FileSelectDialog() function returned error %d", __FUNCTION__, GetLastError());
      return false;
     }
   
   bool res=false;
   if(ChartSetInteger(0,CHART_SHOW,false))
      res=ChartScreenShot(0, file_names[0], GRAPH_WIDTH, GRAPH_HEIGHT);
   ChartSetInteger(0,CHART_SHOW,true);
   return(res);
  }