//+------------------------------------------------------------------+
//| Demo_FileWriteDouble.mq5 |
//| Copyright 2013, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.00"
//--- montrons la fenêtre des paramètres d'entrée au lancement du script
#property script_show_inputs
//--- les paramètres pour la réception des données du terminal
input string InpSymbolName="EURJPY"; // la paire de devise
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_M15; // le temps trame
input int InpMAPeriod=10; // la période du lissage
input int InpMAShift=0; // le déplacement de l'indicateur
input ENUM_MA_METHOD InpMAMethod=MODE_SMA; // le type du lissage
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE; // le type du prix
input datetime InpDateStart=D'2013.01.01 00:00'; // la date de commencement du copiage des données
//--- les paramètres pour l'enregistrement des données au fichier
input string InpFileName="MA.csv"; // le nom du fichier
input string InpDirectoryName="Data"; // le nom du répertoire
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date_finish=TimeCurrent();
double ma_buff[];
datetime time_buff[];
int size;
//--- recevrons le handle de l'indicateur MA
ResetLastError();
int ma_handle=iMA(InpSymbolName,InpSymbolPeriod,InpMAPeriod,InpMAShift,InpMAMethod,InpAppliedPrice);
if(ma_handle==INVALID_HANDLE)
{
//--- on n'a pas réussi de recevoir le hadle de l'indicateur
PrintFormat("L'erreur de la réception du handle de l'indicateur. Le code de l'erreur = %d",GetLastError());
return;
}
//--- on se trouve dans le cycle, pendant que l'indicateur ne compte pas toutes ses valeurs
while(BarsCalculated(ma_handle)==-1)
Sleep(20); // le retard pour que l'indicateur puisse de calculer ses valeurs
PrintFormat("Les valeurs de l'indicateur seront enregistrées au fichier, à partir de %s",TimeToString(InpDateStart));
//--- copions les valeurs de l'indicateur
ResetLastError();
if(CopyBuffer(ma_handle,0,InpDateStart,date_finish,ma_buff)==-1)
{
PrintFormat("On n'a pas réussi de copier les valeurs de l'indicateur. Le code de l'erreur = %d",GetLastError());
return;
}
//--- copions le temps de l'apparition des barres correspondantes
ResetLastError();
if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
{
PrintFormat("On n'a pas réussi de copier les valeurs du temps. Le code de l'erreur = %d",GetLastError());
return;
}
//---recevrons la taille du tampon
size=ArraySize(ma_buff);
//--- désallouons la mémoire occupée par l'indicateur
IndicatorRelease(ma_handle);
//--- ouvrirons le fichier pour l'enregistrement des valeurs de l'indicateur (s'il n'existe pas, il sera créé automatiquement)
ResetLastError();
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
if(file_handle!=INVALID_HANDLE)
{
PrintFormat("Le fichier %s est ouvert pour l'enregistrement",InpFileName);
PrintFormat("La voie vers le fichier: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
//--- d'abord enregistrons la taille de l'extrait des données
FileWriteDouble(file_handle,(double)size);
//--- enregistrons le temps et les valeurs de l'indicateur dans le fichier
for(int i=0;i<size;i++)
{
FileWriteDouble(file_handle,(double)time_buff[i]);
FileWriteDouble(file_handle,ma_buff[i]);
}
//--- fermons le fichier
FileClose(file_handle);
PrintFormat("Les données sonr enregistrés, le fichier %s est fermé",InpFileName);
}
else
PrintFormat("On n'a pas réussi d'ouvrir le fichier %s, Le code de l'erreur = %d",InpFileName,GetLastError());
} |