//--- description
#property description "Le script dessine un objet graphique \"Vague de Correction d'Elliott\"."
#property description "Les coordonnées du point d'ancrage sont définies en pourcentage de la taille de "
#property description "la fenêtre du graphique."
//--- affichage de la fenêtre des paramètres d'entrée lors du lancement du script
#property script_show_inputs
//--- paramètres d'entrée du script
input string InpName="ElliotWave3"; // nom de l'objet
input int InpDate1=10; // Date du premier point, %
input int InpPrice1=90; // Prix du premier point, %
input int InpDate2=30; // Date du second point, %
input int InpPrice2=10; // Prix du second point, %
input int InpDate3=50; // Date du troisième point, %
input int InpPrice3=40; // Prix du troisième point, %
input ENUM_ELLIOT_WAVE_DEGREE InpDegree=ELLIOTT_MINOR; // Niveau
input bool InpDrawLines=true; // Affichage des lignes
input color InpColor=clrRed; // Couleur des lignes
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Style des lignes
input int InpWidth=2; // Largeur des lignes
input bool InpBack=false; // Objet en arrière plan
input bool InpSelection=true; // mise en surbrillance pour le déplacement
input bool InpHidden=true; // caché dans la liste des objets
input long InpZOrder=0; // priorité pour le clic de souris
//+----------------------------------------------------------------------------------------------------+
//| Crée une "Vague de Correction d'Elliott" aux coordonnées données |
//+----------------------------------------------------------------------------------------------------+
bool ElliotWave3Create(const long chart_ID=0, // identifiant du graphique
const string name="ElliotWave3", // nom de la vague
const int sub_window=0, // indice de sous-fenêtre
datetime time1=0, // heure du premier point
double price1=0, // prix du premier point
datetime time2=0, // heure du deuxième point
double price2=0, // prix du deuxième point
datetime time3=0, // heure du troisième point
double price3=0, // prix du troisième point
const ENUM_ELLIOT_WAVE_DEGREE degree=ELLIOTT_MINUETTE, // degré
const bool draw_lines=true, // Affichage des lignes
const color clr=clrRed, // couleur de l'objet
const ENUM_LINE_STYLE style=STYLE_SOLID, // Style des lignes
const int width=1, // Largeur des lignes
const bool back=false, // en arrière plan
const bool selection=true, // mise en surbrillance pour le déplacement
const bool hidden=true, // caché dans la liste des objets
const long z_order=0) // priorité pour le clic de souris
{
//--- définit les coordonnées du point d'ancrage si elles ne sont pas définies
ChangeElliotWave3EmptyPoints(time1,price1,time2,price2,time3,price3);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- Crée une "Vague de Correction d'Elliott" aux coordonnées données
if(!ObjectCreate(chart_ID,name,OBJ_ELLIOTWAVE3,sub_window,time1,price1,time2,price2,time3,price3))
{
Print(__FUNCTION__,
" : échec de création de la \"Vague de Correction d'Elliott\" ! Code d'erreur = ",GetLastError());
return(false);
}
//--- définit le degré (taille de la vague)
ObjectSetInteger(chart_ID,name,OBJPROP_DEGREE,degree);
//--- active (true) ou désactive (false) le mode d'affichage des lignes
ObjectSetInteger(chart_ID,name,OBJPROP_DRAWLINES,draw_lines);
//--- définit la couleur de l'objet
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- définit le style de la ligne
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- définit la largeur des lignes
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- affiche en premier plan (false) ou en arrière-plan (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- active (true) ou désactive (false) le mode de mise en surbrillance du canal pour le déplacement
//--- lors de la création d'un objet graphique utilisant la fonction ObjectCreate, l'objet ne peut pas être
//--- mis en surbrillance et déplacé par défaut. Dans cette méthode, le paramètre de sélection
//--- est vrai par défaut, permettant de mettre en surbrillance et de déplacer l'objet
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- masque (true) ou affiche (false) le nom de l'objet graphique dans la liste des objets
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- définit la priorité pour recevoir l'événement d'un clic de souris dans le graphique
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Déplace le point d'ancrage de la Vague de Correction d'Elliott |
//+----------------------------------------------------------------------------------------------------+
bool ElliotWave3PointChange(const long chart_ID=0, // identifiant du graphique
const string name="ElliotWave3", // nom de l'objet
const int point_index=0, // indice du point d'ancrage
datetime time=0, // coordonnées du point d'ancrage temporel
double price=0) // coordonnées du point d'ancrage prix
{
//--- si la position du point n'est pas définie, le déplace vers la barre courante du prix Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- déplace le point d'ancrage
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
" : impossible de déplacer le point d'ancrage ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Supprime la Vague de Correction d'Elliott |
//+----------------------------------------------------------------------------------------------------+
bool ElliotWave3Delete(const long chart_ID=0, // identifiant du graphique
const string name="ElliotWave3") // nom de l'objet
{
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- supprime l'objet
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
" : échec de la suppression de la \"Vague de Correction d'Elliott\" ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Vérifie les valeurs des points d'ancrage de la Vague de Correction d'Elliott |
//| et définit les valeurs par défaut des points vides |
//+----------------------------------------------------------------------------------------------------+
void ChangeElliotWave3EmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2,
datetime &time3,double &price3)
{
//--- tableau pour récupérer l'heure d'ouverture des 10 dernières barres
datetime temp[];
ArrayResize(temp,10);
//--- récupère les données
CopyTime(Symbol(),Period(),TimeCurrent(),10,temp);
//--- récupère la valeur d'un point du graphique courant
double point=SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- si l'heure du premier point n'est pas définie, il sera placé 9 barres à gauche de la dernière barre
if(!time1)
time1=temp[0];
//--- si le prix du premier point n'est pas défini, il aura la valeur Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- si l'heure du second point n'est pas définie, il sera placé 5 barres à gauche de la dernière barre
if(!time2)
time2=temp[4];
//--- si le prix du deuxième point n'est pas défini, le déplace 300 points plus bas que le premier
if(!price2)
price2=price1-300*point;
//--- si l'heure du troisième point n'est pas définie, il sera placé 1 barre à gauche de la dernière barre
if(!time3)
time3=temp[8];
//--- si le prix du troisième point n'est pas défini, le déplace de 200 points plus bas que le premier
if(!price3)
price3=price1-200*point;
}
//+----------------------------------------------------------------------------------------------------+
//| Fonction de démarrage du script |
//+----------------------------------------------------------------------------------------------------+
void OnStart()
{
//--- vérifie l'exactitude des paramètres d'entrée
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
{
Print("Erreur ! Valeurs incorrectes des paramètres d'entrée !");
return;
}
//--- nombre de barres visibles dans la fenêtre du graphique
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- taille du tableau des prix
int accuracy=1000;
//--- tableaux pour stocker les valeurs de date et de prix à utiliser
//--- pour définir et changer les coordonnées des points d'ancrage de l'objet
datetime date[];
double price[];
//--- allocation mémoire
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- remplit le tableau de dates
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("N'a pas réussi à copier les valeurs de l'heure ! Code d'erreur = ",GetLastError());
return;
}
//--- remplit le tableau des prix
//--- trouve les valeurs les plus élevées et les plus faibles du graphique
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- définit un changement de prix et remplit le tableau
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- définit les points pour dessiner la Vague de Correction d'Elliott
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
//--- Crée la Vague de Correction d'Elliott
if(!ElliotWave3Create(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
InpDegree,InpDrawLines,InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redéssine le graphique et attend 1 seconde
ChartRedraw();
Sleep(1000);
//--- déplace maintenant les points d'ancrage
//--- compteur de boucle
int v_steps=accuracy/5;
//--- déplace le troisième point d'ancrage
for(int i=0;i<v_steps;i++)
{
//--- utilise la valeur suivante
if(p3<accuracy-1)
p3+=1;
//--- déplace le point
if(!ElliotWave3PointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
}
//--- délai de 1 seconde
Sleep(1000);
//--- compteur de boucle
v_steps=accuracy*4/5;
//--- déplace le premier et le deuxième point d'ancrage
for(int i=0;i<v_steps;i++)
{
//--- utilise les valeurs suivantes
if(p1>1)
p1-=1;
if(p2<accuracy-1)
p2+=1;
//--- décale les points
if(!ElliotWave3PointChange(0,InpName,0,date[d1],price[p1]))
return;
if(!ElliotWave3PointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
}
//--- délai de 1 seconde
Sleep(1000);
//--- supprime l'objet du graphique
ElliotWave3Delete(0,InpName);
ChartRedraw();
//--- délai de 1 seconde
Sleep(1000);
//---
} |
