MathArctan

double  MathArctan(
   double  value      // Tangens
   );

#define GRAPH_WIDTH  750
#define GRAPH_HEIGHT 350
 
#include <Graphics\Graphic.mqh>
 
CGraphic ExtGraph;
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
   vector delta=vector::Full(101,2*M_PI/100);
   delta[0]=0;
//--- Ermittlung von 101 Werten von 0 bis 2π in der Schrittweite delta
   vector X=delta.CumSum();
//--- Berechnung des Wertes des Arkustangens für jeden Wert des Vektors X
   vector Y=MathArctan(X);
 
//--- Übertragen der berechneten Werte von Vektoren in Arrays
   double x_array[],y_array[];
   X.Swap(x_array);
   Y.Swap(y_array);
 
//--- Zeichne die Kurve der berechneten Vektorwerte
   CurvePlot(x_array,y_array,clrDodgerBlue);
 
//--- warte auf das Drücken der Escape- oder PgDn-Taste, um das Diagramm zu löschen (einen Screenshot zu erstellen) und die Arbeit zu beenden
   while(!IsStopped())
     {
      if(StopKeyPressed())
         break;
      Sleep(16);
     }
 
//--- aufräumen
   ExtGraph.Destroy();
  }
//+------------------------------------------------------------------+
//| Wenn ESC gedrückt wird, wird 'true' zurückgeben,                 |
//| bei PgDn entsteht ein Screenshot und 'true' wird zurückgegeben   |
//| Andernfalls wird 'false' zurückgegeben                           |
//+------------------------------------------------------------------+
bool StopKeyPressed()
  {
//--- wenn ESC gedrückt wird, wird 'true' zurückgeben
   if(TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)!=0)
      return(true);
//--- wird PgDn gedrückt und ein Bildschirmfoto des Graphen erfolgreich aufgenommen, wird 'true' zurückgegeben
   if(TerminalInfoInteger(TERMINAL_KEYSTATE_PAGEDOWN)!=0 && MakeAndSaveScreenshot(MQLInfoString(MQL_PROGRAM_NAME)+"_Screenshot"))
      return(true);
//--- gib 'false' zurück
   return(false);
  }
//+------------------------------------------------------------------+
//| Erstellen eines Graph-Objekts und Zeichnen einer Kurve           |
//+------------------------------------------------------------------+
void CurvePlot(double &x_array[], double &y_array[], const color colour)
  {
   ExtGraph.Create(ChartID(), "Graphic", 0, 0, 0, GRAPH_WIDTH, GRAPH_HEIGHT);
   ExtGraph.CurveAdd(x_array, y_array, ColorToARGB(colour), CURVE_LINES);
   ExtGraph.IndentUp(30);
   ExtGraph.CurvePlotAll();
   string text1="Press ESC to delete the graph and stop the script, or";
   string text2="Press PgDn to create a screen, delete the graph and stop the script";
   ExtGraph.TextAdd(54, 9, text1, ColorToARGB(clrBlack));
   ExtGraph.TextAdd(54,21, text2, ColorToARGB(clrBlack));
   ExtGraph.Update();
  }
//+------------------------------------------------------------------+
//| Bildschirmfoto machen und speichern des Bildes in einer Datei    |
//+------------------------------------------------------------------+
bool MakeAndSaveScreenshot(const string file_name)
  {
   string file_names[];
   ResetLastError();
   int selected=FileSelectDialog("Save Picture", NULL, "All files (*.*)|*.*", FSD_WRITE_FILE, file_names, file_name+".png");
   if(selected<1)
     {
      if(selected<0)
         PrintFormat("%s: FileSelectDialog() function returned error %d", __FUNCTION__, GetLastError());
      return false;
     }
   
   bool res=false;
   if(ChartSetInteger(0,CHART_SHOW,false))
      res=ChartScreenShot(0, file_names[0], GRAPH_WIDTH, GRAPH_HEIGHT);
   ChartSetInteger(0,CHART_SHOW,true);
   return(res);
  }