should define your key file

Author: turangozukara

.gitignore

@@ -0,0 +1,18 @@
+# Local .terraform directories
+**/.terraform/*
+
+# Terraform lockfile
+.terraform.lock.hcl
+
+# .tfstate files
+*.tfstate
+*.tfstate.*
+
+# Crash log files
+crash.log
+
+# Exclude all .tfvars files, which are likely to contain sensitive data, such as
+# password, private keys, and other secrets. These should not be part of version
+# control as they are data points which are potentially sensitive and subject
+# to change depending on the environment.
+*.tfvars

README.md

@@ -0,0 +1,19 @@
+Terraform Module to provision an AWS EC2 instance with the latest amazon linux 2 ami and installed docker in it.
+
+Not intended for production use. It is an example module.
+
+It is just for showing how to create a publish module in Terraform Registry.
+
+Usage:
+
+```hcl
+
+provider "aws" {
+ region = "us-east-1"
+}
+
+module "docker_instance" {
+ source = "turangozukara/docker-instance-module/aws"
+ key_name = "yourkeyname"
+}
+```

main.tf

@@ -0,0 +1,66 @@
+data "aws_ami" "amazon-linux-2023" {
+ owners = ["amazon"]
+ most_recent = true
+
+ filter {
+ name = "root-device-type"
+ values = ["ebs"]
+ }
+
+ filter {
+ name = "virtualization-type"
+ values = ["hvm"]
+ }
+
+ filter {
+ name = "architecture"
+ values = ["x86_64"]
+ }
+
+ filter {
+ name = "owner-alias"
+ values = ["amazon"]
+ }
+
+ filter {
+ name = "name"
+ values = ["al2023-ami-2023*"]
+ }
+}
+
+resource "aws_instance" "tfmyec2" {
+ ami = data.aws_ami.amazon-linux-2023.id
+ instance_type = var.instance_type
+ count = var.num_of_instance
+ key_name = var.key_name
+ vpc_security_group_ids = [aws_security_group.tf-sec-gr.id]
+ user_data = templatefile("${abspath(path.module)}/userdata.sh", {myserver = var.server-name})
+ tags = {
+ Name = var.tag
+ }
+}
+
+resource "aws_security_group" "tf-sec-gr" {
+ name = "${var.tag}-terraform-sec-grp"
+ tags = {
+ Name = var.tag
+ }
+
+ dynamic "ingress" {
+ for_each = var.docker-instance-ports
+ iterator = port
+ content {
+ from_port = port.value
+ to_port = port.value
+ protocol = "tcp"
+ cidr_blocks = ["0.0.0.0/0"]
+ }
+ }
+
+ egress {
+ from_port =0
+ protocol = "-1"
+ to_port =0
+ cidr_blocks = ["0.0.0.0/0"]
+ }
+}

outputs.tf

@@ -0,0 +1,11 @@
+output "instance_public_ip" {
+ value = aws_instance.tfmyec2.*.public_ip
+}
+
+output "sec_gr_id" {
+ value = aws_security_group.tf-sec-gr.id
+}
+
+output "instance_id" {
+ value = aws_instance.tfmyec2.*.id
+}

userdata.sh

@@ -0,0 +1,10 @@
+#!/bin/bash
+hostnamectl set-hostname ${myserver}
+dnf update -y
+dnf install docker -y
+systemctl start docker
+systemctl enable docker
+usermod -a -G docker ec2-user
+# install docker-compose
+curl -SL https://github.com/docker/compose/releases/download/v2.17.3/docker-compose-linux-x86_64 -o /usr/local/bin/docker-compose
+chmod +x /usr/local/bin/docker-compose

variables.tf

@@ -0,0 +1,29 @@
+variable "instance_type" {
+ type = string
+ default = "t2.micro"
+}
+
+variable "key_name" {
+ type = string
+}
+
+variable "num_of_instance" {
+ type = number
+ default = 1
+}
+
+variable "tag" {
+ type = string
+ default = "Docker-Instance"
+}
+
+variable "server-name" {
+ type = string
+ default = "docker-instance"
+}
+
+variable "docker-instance-ports" {
+ type = list(number)
+ description = "docker-instance-sec-gr-inbound-rules"
+ default = [22, 80, 8080]
+}

versions.tf

@@ -0,0 +1,8 @@
+terraform {
+ required_providers {
+ aws = {
+ source = "hashicorp/aws"
+ version = "~> 5.0"
+ }
+ }
+}