ci: Add jacoco-convention.gradle.kts (#22)

Author: petertrr

build.gradle.kts

@@ -4,9 +4,9 @@ import io.gitlab.arturbosch.detekt.Detekt
 import org.jetbrains.kotlin.gradle.targets.jvm.tasks.KotlinJvmTest
 
 plugins {
- alias(libs.plugins.kotlin.multiplatform)
+ kotlin("multiplatform")
+ id("jacoco-convention")
  alias(libs.plugins.detekt)
- jacoco
 }
 
 configureVersioning()
@@ -65,25 +65,3 @@ dependencies {
 tasks.withType<Detekt> {
  tasks.getByName("check").dependsOn(this)
 }
-
-// configure Jacoco-based code coverage reports for JVM tests executions
-jacoco {
- toolVersion = "0.8.7"
-}
-val jvmTestTask by tasks.named<KotlinJvmTest>("jvmTest") {
- configure<JacocoTaskExtension> {
- // this is needed to generate jacoco/jvmTest.exec
- isEnabled = true
- }
-}
-val jacocoTestReportTask by tasks.register<JacocoReport>("jacocoTestReport") {
- executionData(jvmTestTask.extensions.getByType(JacocoTaskExtension::class.java).destinationFile)
- additionalSourceDirs(kotlin.sourceSets["commonMain"].kotlin.sourceDirectories)
- classDirectories.setFrom(file("$buildDir/classes/kotlin/jvm/main"))
- reports {
- xml.required.set(true)
- html.required.set(true)
- }
-}
-jvmTestTask.finalizedBy(jacocoTestReportTask)
-jacocoTestReportTask.dependsOn(jvmTestTask)

buildSrc/build.gradle.kts

@@ -7,8 +7,10 @@ repositories {
  mavenCentral()
 }
 
+val libs = extensions.getByType<VersionCatalogsExtension>().named("libs")
 dependencies {
  implementation("org.ajoberstar.reckon:reckon-gradle:0.13.1")
  implementation("org.jetbrains.dokka:dokka-gradle-plugin:1.6.10")
  implementation("io.github.gradle-nexus:publish-plugin:1.1.0")
+ implementation("org.jetbrains.kotlin:kotlin-gradle-plugin:${libs.findVersion("kotlin").get()}")
 }

buildSrc/settings.gradle.kts

@@ -0,0 +1,9 @@
+enableFeaturePreview("VERSION_CATALOGS")
+
+dependencyResolutionManagement {
+ versionCatalogs {
+ create("libs") {
+ from(files("../gradle/libs.versions.toml"))
+ }
+ }
+}

buildSrc/src/main/kotlin/io/github/petertrr/jacoco-convention.gradle.kts

@@ -0,0 +1,39 @@
+import org.gradle.api.tasks.testing.Test
+import org.gradle.kotlin.dsl.named
+import org.gradle.kotlin.dsl.getValue
+import org.gradle.kotlin.dsl.provideDelegate
+import org.gradle.kotlin.dsl.register
+import org.gradle.testing.jacoco.plugins.JacocoTaskExtension
+import org.gradle.testing.jacoco.tasks.JacocoReport
+
+plugins {
+ kotlin("multiplatform")
+ jacoco
+}
+
+kotlin {
+ // to register `KotlinJvmTest` tasks before configuring Jacoco
+ jvm()
+}
+
+// configure Jacoco-based code coverage reports for JVM tests executions
+jacoco {
+ toolVersion = "0.8.7"
+}
+val jvmTestTask by tasks.named<Test>("jvmTest") {
+ configure<JacocoTaskExtension> {
+ // this is needed to generate jacoco/jvmTest.exec
+ isEnabled = true
+ }
+}
+val jacocoTestReportTask by tasks.register<JacocoReport>("jacocoTestReport") {
+ executionData(jvmTestTask.extensions.getByType(JacocoTaskExtension::class.java).destinationFile)
+ additionalSourceDirs(kotlin.sourceSets["commonMain"].kotlin.sourceDirectories)
+ classDirectories.setFrom(file("$buildDir/classes/kotlin/jvm/main"))
+ reports {
+ xml.required.set(true)
+ html.required.set(true)
+ }
+}
+jvmTestTask.finalizedBy(jacocoTestReportTask)
+jacocoTestReportTask.dependsOn(jvmTestTask)